// Persistence Of Vision Ray Tracer Scene Description File
// -------------------------------------------------------
// File: @(#)kiopov_trans.pov
// Desciption: title image for POV KIO slave
// Creation Date: $ 30 May 2004, 21:19:00 $
// Last modified: $ 08 Oct 2005, 18:55:57 $
// Author: Christoph Hormann <chris_hormann@gmx.de>
//
// -w180 -h180 +a0.2 +am2 +ua
//

#declare VARIANT_TEST=0;    // normal render (for testing)
#declare VARIANT_ALPHA=1;   // alpha render (for foreground)
#declare VARIANT_BKG=2;     // background render (for shadow color)
#declare VARIANT_SHADOW=3;  // shadow render (for shadow shape)


#ifndef (Variant)
	#declare Variant=VARIANT_TEST;
#end

#declare use_hdri=true;

#version unofficial megapov 1.2;

global_settings {
  assumed_gamma 1
  max_trace_level 15
	tone_mapping { function { min(1, x) } }

	#if (Variant != VARIANT_SHADOW)
		radiosity {
			pretrace_start 0.08
			pretrace_end   0.01
			count 120

			nearest_count 5
			error_bound 0.4
			recursion_limit 1

			low_error_factor .5
			gray_threshold 0.0
			minimum_reuse 0.015
			brightness 0.85

			adc_bailout 0.01/2
		}
	#end
}

camera {
  location  <-1.2, -6.0, 3.5>
  up z
  sky z
  look_at   <-0.2, 0.0, 0.6> 
  right x*(image_width/image_height)
  angle 19
}

light_source {
  <2000, -1600, 2000>*0.5
  color rgb <2.2, 1.8, 1.5>
	area_light 100*x 100*y  6, 6 jitter orient circular adaptive 1
}

#declare Angle=10;

#if (use_hdri)
sphere {
  0,1
  pigment {
    image_map {
      hdr "patio.hdr"
      once
      interpolate 2
      map_type 2
    }
    scale 2 translate -y
  }
  finish {
    ambient 1
    diffuse 0
  }

  scale 2000
  rotate 90*x
  hollow
  rotate Angle*z
 no_image
}

#else

sky_sphere {
  pigment {
    gradient z
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.2 rgb <0.2,0.3,0.9>]
    }
  }
}

#end

// ----------------------------------------

plane {
  z, 0.0
  texture { 
		pigment { color rgb 1 }
		#switch (Variant)
			#case (VARIANT_TEST)
				finish { ambient 0 diffuse 0.5 }
			#break
			#case (VARIANT_ALPHA)
				finish { ambient 0 diffuse 0.5 }
			#break
			#case (VARIANT_BKG)
				finish { ambient 0 diffuse 0.25 }
			#break
			#case (VARIANT_SHADOW)
				finish { ambient 0.05 diffuse 1.05 }
			#break
		#end
  }
	#if (Variant = VARIANT_ALPHA)
		no_image
	#end
}

#declare Tex_Metal=
  texture {
    pigment { color rgb <1.0, 0.6, 0.2> }
    finish{
      diffuse 0.4
      ambient 0.0
      roughness 0.007
      reflection { 0.5 metallic }
      conserve_energy
    }
  }

#declare Tex_Metal2=
  texture {
    pigment { color rgb <0.1, 0.23, 1.0> }
    finish{
      diffuse 1.0
      ambient 0.0
      specular 0.6
        roughness 0.012
      reflection { 0.15 metallic }
      conserve_energy
    }
  }

#include "glass.inc"

#declare Mat_Glass1=
  material {
    texture {
      pigment { color rgbt <0.5, 0.5, 0.75, 0.9> }
      finish {
        reflection { 0.2, 1.0 fresnel on }
        diffuse 0.5
        ambient 0
        specular 0.2
        roughness 0.007
        conserve_energy
      }
    }
    interior {
      I_Glass2
      fade_color Col_Amethyst_03
      fade_distance 0.2
    }
  }

// ----------------------------------------

#declare fn_Spline1=
function {
	spline {
		linear_spline
		-100, < 0.0, 0>,
		-10, < 0.0, 0>,
		-0.3, < 0.0, 0>,
		-0.295, < 0.0, 0.1>,
		-0.165, < 1.0, 0.9>,
		-0.16, < 1.0, 1>,
		-0.14, < 1.0, 1>,
		-0.12, < 1.0, 1>,
		-0.10, < 1.0, 1>,
		-0.08, < 1.0, 1>,
		-0.06, < 1.0, 1>,
		 0.06, < 1.0, 1>,
		 0.08, < 1.0, 1>,
		 0.10, < 1.0, 1>,
		 0.12, < 1.0, 1>,
		 0.14, < 1.0, 1>,
		 0.16, < 1.0, 1>,
		 0.165, < 1.0, 0.9>,
		 0.295, < 0.0, 0.1>,
		 0.3, < 0.0, 0>,
		 10, < 0.0, 0> ,
		 100, < 0.0, 0>
	}
}

#include "iso_csg.inc"
#include "shapes.inc"

#local fn_dents=
function(x) {
	fn_Spline1(x-int(x)-0.5).y
}

#local fn_cyl=
function {
	f_r(x, y, 0)-0.5
	-fn_dents(abs(atan2(x,y)*4/pi))*0.18
}

#declare Povray_LogoX =
merge {
   difference {
      cone {2*y, 1, -4*y, 0}
      sphere {2*y, 1.4 scale <1,1,2>}
   }
   difference {
      sphere {0, 1 scale <2.6, 2.2, 1>}
      sphere {0, 1 scale <2.3, 1.8, 2> translate <-0.35, 0, 0>}
      rotate z*30 translate 2*y
   }
   rotate <0, 0, -25>
   translate <-0.5,-0.35,0>
   scale 1/4
}

union {
	difference {
		isosurface {		
			function {
				fn_cyl(x,y,z)
			}
			max_gradient 5		
			contained_by { box { <-1,-1,0.03>,<1,1,0.35> } }
		}
		Round_Cylinder_Merge(<0,0,0.28>, 0.6*z, 0.4, 0.03)
		cylinder { -z, z, 0.1 }
		texture { Tex_Metal2 }
	}

	difference {
		Round_Cylinder_Union(<0,0,0>, 0.3*z, 0.29, 0.03)
		cylinder { -z, z, 0.1 }
		texture { Tex_Metal2 }
	}

	object {
		Povray_LogoX
		rotate 90*x
		scale 0.75
		translate <0.26,0,0.75>
		texture { Tex_Metal }
	}

	sphere {
		2*y, 1
		rotate <0, 0, -25>
		translate <-0.5,-0.35,0>
		scale 1/4
		rotate 90*x
		scale 0.75
		translate <0.26,0,0.75>
		material { Mat_Glass1 }
	}
	#if ((Variant = VARIANT_BKG) | (Variant = VARIANT_SHADOW))
		no_image
	#end
}