The agate face
This is the scene i created for the
POV-Ray shortest code contest, round 3. Have a look at the
results
page for the other entries.
|
This image made the second place in that contest meaning it was the image with the highest number of votes when not taking into account the size of the source (artistic category).
The following is the code for the image - 238 bytes:
background{rgb<.5.7,1>}global_settings{radiosity{error_bound.5count 99}
ambient_light#local _=function{pattern{agate turbulence 1octaves 9}}0}
isosurface{function{(y+.07-_(x+9,y,z)*.115)/20}accuracy 1e-5pigment{rgb 1}}
light_source{5<8,4,2>}
This minimum size version is of course not well readable, the following is the expanded and commented version:
// background color
background {
rgb <.5.7,1>
}
global_settings {
// radiosity settings - somewhat higher quality than default
// fairly slow due to default recursion_limit 3
radiosity {
error_bound .5
count 99
}
// alternative settings for faster render:
//radiosity { } // somewhat faster
//radiosity { recursion_limit 1 } // much faster
/*
radiosity { // faster and fairly good quality
error_bound .5
count 99
recursion_limit 1
}
*/
// slightly shorter than 'finish{ambient 0}' for the isosurface
ambient_light 0
}
// this is placed between 'ambient_light' and '0' in the short version
// to save one character
// a simple pattern function
#local _=
function {
pattern {
agate
turbulence 1
// you can try higher values here but will loose the 'face'
octaves 9
}
}
isosurface {
// the surface shape:
// horizontal plane displaced by the pattern function
// scaling to avoid a max_gradient statement
function {
(y + .07 - _(x+9,y,z)*.115)/20
}
accuracy 1e-5
// plain color pigment
pigment { rgb 1 }
}
// illumination - a simple point light
light_source{
5
<8,4,2>
}
Here are two earlier versions of the scene:
|
|
I also made a short animation of a slightly extended version:
