//  Persistence of Vision Ray Tracer Scene Description File
//
//  Water Tunnel Scene: Water
//
//  Copyright April-June 2001 Christoph Hormann
//

#version unofficial MegaPov 0.7;

//------( Ground Pigment )----------------------

#macro Pig02(Bright)
  bozo
  color_map {
    [0.39 color rgb <0.88, 0.87, 0.65>*Bright ]
    [0.42 color rgb <0.88, 0.87, 0.90>*Bright ]
    [0.61 color rgb <0.88, 0.87, 0.90>*Bright ]
    [0.64 color rgb <0.72, 0.65, 0.54>*0.3*Bright ]
  }
  turbulence 0.4
  scale 0.6
#end

#macro Pig01(Bright)
  granite
  pigment_map {
    [0.35 color rgb <0.32, 0.35, 0.34>*0.6*Bright ]
    [0.42 color rgb <0.85, 0.83, 0.65>*0.8*Bright ]
    [0.61 color rgb <0.85, 0.83, 0.65>*0.8*Bright ]
    [0.65 Pig02(Bright)  ]
  }
  turbulence 0.6
  scale 2
#end


#macro Ground_Pig_01(Bright)
    bozo
    pigment_map {
      [0.41 Pig01(Bright)  ]
      [0.43 Pig02(Bright)  ]
      [0.62 Pig02(Bright)  ]
      [0.64 color rgb <0.88, 0.87, 0.65>*Bright ]
    }
    turbulence 0.25
    scale 0.3
    scale 1/20
#end

//------( Ground Object )----------------------

#declare Ground=
union {
  sphere {
    -200*z, 198.48
  }

  plane {
    z, -5
  }
  texture{
    pigment {
      spherical
      pigment_map {
        [0.1 Ground_Pig_01(0.2) ]
        [0.8 Ground_Pig_01(0.6) ]
      }
      scale 20
    }
    finish {
      ambient 0
      diffuse 0.6
    }
    normal {
      wrinkles 0.9
      scale 0.3
    }
  }
}

object { Ground }


//------( Water )----------------------


#declare fnRMF=function{"ridgedMF",<0.07, 2.2,  7, 0.6, 0.9>}


#declare M_Watx4=
  material {

    texture {
      pigment { rgbt <0.2, 0.22, 0.21, 0.94> }
      finish {
        specular 0.45
        roughness 0.047
        ambient 0.0
        diffuse 0.005

        reflection_type 1
        reflection_max <1.1, 1.1, 1.2>
        reflection_min 0.0
        conserve_energy
        metallic 0.5
      }
    }
    interior {
      ior 1.32
      fade_distance 2
      fade_power 1001.0
      fade_color <0.02, 0.20, 0.06>
    }
  }


#declare WaterISO=
isosurface {
  function {
    z-(fnRMF((x-12)*5.5*1.42, y*4*1.42, 0)-0.4)*0.052
  }
  method 2
  max_gradient 3
  //eval
  accuracy 0.01
  contained_by { box { <-1000, -1000, -4>, <1000, 1000, 0.06> } }

}


merge {
  difference {
    object { WaterISO }
    cylinder { -z*4.01, 0.11*z, 5 }
    photons{ ignore_photons }
  }
  intersection {
    object { WaterISO }
    cylinder { -z*4.01, 0.11*z, 5.0001 }
    photons {target reflection on refraction on ignore_photons }
  }

  material { M_Watx4 }

  translate -1*x
  translate -0.3*z
}